Orientações para dimensionamento do Atlas

Recursos para dimensionamento do Atlas

O dimensionamento automático permite que os clusters ajustem automaticamente seu tier, capacidade de armazenamento ou ambos, em resposta ao uso em tempo real. O Atlas usa mecanismos de dimensionamento automático complementares:

• O auto-scaling reativo analisa a utilização atual da CPU e da memória para trigger eventos de dimensionamento com base no uso sustentado de recursos, alto ou baixo. O dimensionamento automático reativo ocorre após as mudanças na carga de trabalho e lida com o upscaling e o downscaling.

• O auto-scaling preditivo usa o aprendizado de máquina para antecipar futuras necessidades de dimensionamento com base em padrões de uso históricos e em tentativas de escalonamento antes dos picos de volume de trabalho cíclicos que ele acredita que chegarão. O auto-scaling preditivo está disponível para clusters qualificados e oferece suporte apenas ao upscaling. O downscaling permanece reativo.

Consulte Dimensionamento da camada do cluster para saber mais sobre as condições em que o Atlas dimensiona os nós do cluster para cima ou para baixo. Você também pode especificar uma faixa de tamanhos máximos e mínimos de cluster para os quais seu cluster pode escalar automaticamente para garantir o desempenho mínimo ou os custos de controle. Em geral, o Atlas não dimensiona um cluster se o dimensionamento resultar em uma camada fora do intervalo de tamanho especificado, embora a camada do cluster e o armazenamento possam ser dimensionados em paralelo se as necessidades do disco exigirem. O Atlas também não será dimensionado se o uso da memória ou da CPU exceder a capacidade do nível dimensionado.

O dimensionamento automático é mais adequado para cargas de aplicativo em crescimento ou queda constante e padrões de carga de trabalho cíclicos. Para picos de tráfego únicos e inesperados, como lançamentos de produtos ou eventos sem precedentes, faça a pré-dimensionar programaticamente. O dimensionamento automático reativo introduz um atraso limitado para evitar o impacto do aplicativo, e o dimensionamento automático preditivo lida apenas com padrões recorrentes.

Os modelos de implementação do Atlas , conforme referenciados nas Topologias de implementação recomendadas, fornecem opções de dimensionamento horizontal e vertical. Especificamente, a fragmentação distribui dados entre várias máquinas, o que é útil quando nenhum servidor único pode lidar com suas cargas de trabalho. A fragmentação segue uma arquitetura de nada compartilhado, uma arquitetura de computação distribuída em que nenhum dos nós compartilha recursos entre si.Consulte Escolher uma chave de shard para saber mais sobre a escolha ideal de uma chave de shard que permite ao MongoDB distribuir documentos uniformemente em todo o cluster e, ao mesmo tempo, facilitar padrões de query comuns. Além disso, consulte Práticas recomendadas de desempenho: fragmentação para saber mais sobre as principais estratégias de fragmentação, como fragmentação à distância, fragmentação com hash e fragmentação por zonas.

A atualização de um Atlas cluster para a próxima camada disponível do Atlas está disponível por meio da GUI do plano de controle do Atlas , da API de administração do Atlas ou por meio de ferramentas do IaC, como o Atlas Kubernetes Operator, o MongoDB & HashiCorp Terraform ou Atlas CLI.Consulte Orientação para o provisionamento automatizado de infraestrutura do Atlas para saber mais. Alterar uma camada do Atlas , seja para upscaling ou downscaling, permite zero tempo de inatividade. O nível muda de forma contínua, o que envolve a eleição de um membro secundário como substituto, a promoção desse membro secundário a se tornar o novo primário e, em seguida, a restauração ou a substituição do membro com falha para garantir que o cluster retorne à configuração de destino o mais rápido possível . O dimensionamento horizontal ocorre após a implantação com base na ação do administrador , que pode ser acionada a partir de um script programático. Alguns modelos de cluster exigem clusters fragmentados. A partir da versão 8 do MongoDB .0, você pode usar servidores de configuração incorporados para reduzir os custos associados aos servidores de configuração em pequenos clusters fragmentados.

A opção de baixa CPU no Atlas auxilia aplicativos que necessitam de mais memória, mas não tanto poder de processamento. Esta opção oferece instâncias com metade das vCPUs em comparação com o nível Geral do mesmo tamanho de cluster, reduzindo os custos para cargas de trabalho que exigem muita memória, mas não dependem da CPU.

A hierarquização de dados e o arquivamento permitem arquivar dados em armazenamento de baixo custo, enquanto ainda possibilitam consultas junto com dados ativos do cluster, o que é particularmente útil para a retenção de registros a longo prazo. Para otimizar esse processo, o MongoDB recomenda automatizar o arquivamento de dados com regras simples e configuráveis. Consulte Arquivar dados para saber mais sobre os critérios que você pode especificar em uma regra de arquivamento. Para cenários em que a retenção de dados não é uma prioridade, o Atlas oferece a opção de excluir automaticamente dados não utilizados com base em critérios de data. Para dados acessados com pouca frequência, os índices TTL são índices especiais de campo único que removem automaticamente documentos de uma coleção após um período especificado ou em um horário determinado. É especialmente útil para dados como logs, informações de sessão ou dados de eventos que só precisam ser mantidos por um tempo limitado. Para criar um índice TTL, é possível definir um índice em um campo que armazena valores de data e especificar uma duração de existência em segundos.

O Atlas também fornece FERRAMENTAS automatizados, como o Performance Advisor, para identificar e otimizar queries ineficientes adicionando ou removendo um índice ou alterando a estrutura de query do seu cliente. Você pode reduzir o tempo de computação desnecessário e o consumo de recursos seguindo as recomendações práticas do Performance Advisor para melhorar o desempenho da query. Além disso, você pode aproveitar as recomendações de índice inteligentes fornecidas pelo Atlas para melhorar ainda mais a eficiência da recuperação de dados e minimizar os recursos necessários para operações de banco de dados .

Recomendações para dimensionamento do Atlas

Exemplos de Automação: Escalabilidade do Atlas

Os exemplos a seguir habilitam o dimensionamento automático de computação e de armazenamento usando as ferramentas do Atlas para automação.

Esses exemplos também incluem outras configurações recomendadas, tais como:

{
    "clusterType": "REPLICASET",
    "links": [],
    "name": "CustomerPortalProd",
    "mongoDBMajorVersion": "8.0",
    "replicationSpecs": [
      {
        "numShards": 1,
        "regionConfigs": [
          {
            "electableSpecs": {
              "instanceSize": "M30",
              "nodeCount": 3
            },
            "priority": 7,
            "providerName": "GCP",
            "regionName": "EASTERN_US",
            "analyticsSpecs": {
              "nodeCount": 0,
              "instanceSize": "M30"
            },
            "autoScaling": {
              "compute": {
                "enabled": true,
                "scaleDownEnabled": true
              },
              "diskGB": {
                "enabled": true
              }
            },
            "readOnlySpecs": {
              "nodeCount": 0,
              "instanceSize": "M30"
            }
          }
        ],
        "zoneName": "Zone 1"
      }
    ]
  }

atlas cluster create --projectId 5e2211c17a3e5a48f5497de3 --file cluster.json

# Create a Group to Assign to Project
resource "mongodbatlas_team" "project_group" {
  org_id = var.atlas_org_id
  name   = var.atlas_group_name
  usernames = [
    "user1@example.com",
    "user2@example.com"
  ]
}
# Create a Project
resource "mongodbatlas_project" "atlas-project" {
  org_id = var.atlas_org_id
  name = var.atlas_project_name
}
# Assign the team to project with specific roles
resource "mongodbatlas_team_project_assignment" "project_team" {
  project_id = mongodbatlas_project.atlas-project.id
  team_id    = mongodbatlas_team.project_group.team_id
  role_names = ["GROUP_READ_ONLY", "GROUP_CLUSTER_MANAGER"]
}
# Create an Atlas Advanced Cluster
resource "mongodbatlas_advanced_cluster" "atlas-cluster" {
  project_id = mongodbatlas_project.atlas-project.id
  name = "ClusterPortalProd"
  cluster_type = "REPLICASET"
  mongo_db_major_version = var.mongodb_version
  use_effective_fields = true
  replication_specs = [
    {
      region_configs = [
        {
          electable_specs = {
            instance_size = var.cluster_instance_size_name
            node_count    = 3
            disk_size_gb  = var.disk_size_gb
          }
          auto_scaling = {
            disk_gb_enabled = var.auto_scaling_disk_gb_enabled
            compute_enabled = var.auto_scaling_compute_enabled
            compute_max_instance_size = var.compute_max_instance_size
          }
          priority      = 7
          provider_name = var.cloud_provider
          region_name   = var.atlas_region
        }
      ]
    }
  ]
  tags = {
    BU       = "ConsumerProducts"
    TeamName = "TeamA"
    AppName  = "ProductManagementApp"
    Env      = "Production"
    Version  = "8.0"
   Email    = "marissa@example.com"
  }
}
# Outputs to Display
output "atlas_cluster_connection_string" { value = mongodbatlas_advanced_cluster.atlas-cluster.connection_strings.standard_srv }
output "project_name"      { value = mongodbatlas_project.atlas-project.name }

replication_specs = [
  {
    region_configs = [
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 2
        }
        provider_name = "GCP"
        priority      = 7
        region_name   = "NORTH_AMERICA_NORTHEAST_1"
      },
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 3
        }
        provider_name = "GCP"
        priority      = 6
        region_name   = "WESTERN_US"
      }
    ]
  }
]

# Atlas Organization ID
variable "atlas_org_id" {
  type        = string
  description = "Atlas Organization ID"
}
# Atlas Project Name
variable "atlas_project_name" {
  type        = string
  description = "Atlas Project Name"
}
# Atlas Group Name
variable "atlas_group_name" {
  type        = string
  description = "Atlas Group Name"
}
# Atlas Project Environment
variable "environment" {
  type        = string
  description = "The environment to be built"
}
# Cluster Instance Size Name
variable "cluster_instance_size_name" {
  type        = string
  description = "Cluster instance size name"
}
# Cloud Provider to Host Atlas Cluster
variable "cloud_provider" {
  type        = string
  description = "AWS or GCP or Azure"
}
# Atlas Region
variable "atlas_region" {
  type        = string
  description = "Atlas region where resources will be created"
}
# MongoDB Version
variable "mongodb_version" {
  type        = string
  description = "MongoDB Version"
}
# Storage Auto-scaling Enablement Flag
variable "auto_scaling_disk_gb_enabled" {
  type        = bool
  description = "Flag that specifies whether disk auto-scaling is enabled"
}
# Compute Auto-scaling Enablement Flag
variable "auto_scaling_compute_enabled" {
  type        = bool
  description = "Flag that specifies whether cluster tier auto-scaling is enabled"
}
# Disk Size in GB
variable "disk_size_gb" {
  type        = int
  description = "Disk Size in GB"
}

atlas_org_id = "32b6e34b3d91647abb20e7b8"
atlas_project_name = "Customer Portal - Prod"
atlas_group_name = "Atlas Group"
environment = "prod"
cluster_instance_size_name = "M30"
cloud_provider = "AWS"
atlas_region = "US_WEST_2"
mongodb_version = "8.0"
auto_scaling_disk_gb_enabled = true
auto_scaling_compute_enabled = true
disk_size_gb = 40000

# Define the MongoDB Atlas Provider
terraform {
  required_providers {
    mongodbatlas = {
      source = "mongodb/mongodbatlas"
      version = "~> 2.2"
    }
  }
  required_version = ">= 1.0"
}
# Configure the MongoDB Atlas Provider
provider "mongodbatlas" {
  # Legacy API key authentication (backward compatibility)
  public_key  = var.mongodbatlas_public_key
  private_key = var.mongodbatlas_private_key
  # Recommended: Service account authentication
  # Uncomment and configure the following for service account auth:
  # service_account_id = var.mongodb_service_account_id
  # private_key_file   = var.mongodb_service_account_key_file
}

terraform init

terraform plan

terraform apply