Guía para la escalabilidad de Atlas

Características para la escalabilidad de Atlas

El escalado automático permite que los clústeres ajusten automáticamente su nivel, capacidad de almacenamiento o ambos, según el uso en tiempo real. Atlas analiza el uso de la CPU y la memoria para determinar cuándo y si es necesario escalar el nivel del clúster hacia arriba o hacia abajo. Consulte Escalado de niveles de clúster para obtener más información sobre las condiciones bajo las cuales Atlas escala verticalmente o verticalmente los nodos de su clúster. También puede especificar un rango de tamaños máximos y mínimos de clúster al que su clúster puede escalar automáticamente para garantizar un rendimiento mínimo o controlar los costos. Atlas no escalará un clúster si el nuevo nivel está fuera del rango de tamaño especificado o si el uso de memoria excede la capacidad del nuevo nivel. El escalado automático se limita con un retraso para escalar verticalmente un nivel de clúster y garantizar que no afecte a la aplicación. Por lo tanto, es más adecuado para una carga de aplicación en constante crecimiento o decrecimiento, no para picos repentinos en los que la base de datos se ve inundada de uso. Si su carga de trabajo experimenta picos frecuentes o si espera un gran aumento de tráfico debido a un evento o un lanzamiento, MongoDB recomienda preescalar programáticamente.

Plantillas de implementación de Atlas, como se hace referencia en el Las topologías de implementación recomendadas ofrecen opciones de escalado horizontal y vertical. En concreto, la fragmentación distribuye los datos entre varias máquinas, lo cual resulta útil cuando ningún servidor puede gestionar las cargas de trabajo. La fragmentación sigue una arquitectura de computación distribuida donde ningún nodo comparte recursos.Consulte "Elegir una clave de fragmentación" para obtener más información sobre la clave de fragmentación ideal que permite a MongoDB distribuir los documentos de forma uniforme en todo el clúster, facilitando al mismo tiempo patrones de consulta comunes. Además, consulte "Mejores prácticas de rendimiento: fragmentación" para obtener más información sobre las estrategias de fragmentación clave, como la fragmentación por rangos, la fragmentación hash y la fragmentación por zonas.

La actualización de un clúster Atlas al siguiente nivel disponible se realiza a través de la interfaz gráfica de usuario (GUI) del plano de control de Atlas, la API de administración de Atlas o herramientas de IaC, como el operador de Kubernetes de Atlas, Terraform de MongoDB y HashiCorp o la CLI de Atlas.Consulte la Guía para el aprovisionamiento automatizado de infraestructura de Atlas para obtener más información. Cambiar un nivel de Atlas, ya sea para aumentar o reducir la escala, permite cero tiempo de inactividad. El nivel cambia de forma continua, lo que implica elegir un miembro secundario como reemplazo, promover este miembro secundario para que se convierta en el nuevo principal y, a continuación, restaurar o reemplazar el miembro que falla para garantizar que el clúster vuelva a su configuración de destino lo antes posible. El escalado horizontal se realiza después de la implementación según la acción del administrador, que puede activarse desde un script programático. Algunas plantillas de clúster requieren clústeres fragmentados. A partir de la versión de MongoDB,8.0 puede utilizar servidores de configuración integrados para reducir los costes asociados a los servidores de configuración en clústeres fragmentados pequeños.

La opción de bajo consumo de CPU en Atlas facilita el uso de aplicaciones que requieren más memoria, pero no tanta potencia de procesamiento. Esta opción proporciona instancias con la mitad de vCPU en comparación con el nivel General del mismo tamaño de clúster, lo que reduce los costos de las cargas de trabajo que consumen mucha memoria, pero no están limitadas por la CPU.

La organización por niveles y el archivado de datos permiten archivar datos en un almacenamiento de bajo coste y, al mismo tiempo, habilitar consultas junto con datos de clúster en tiempo real, lo cual resulta especialmente útil para la retención de registros a largo plazo. Para optimizar este proceso, MongoDB recomienda automatizar el archivado de datos con reglas sencillas y configurables. Consulte Archivar datos para obtener más información sobre los criterios que puede especificar en una regla de archivado. Para situaciones en las que la retención de datos no es una prioridad, Atlas ofrece la opción de eliminar automáticamente los datos no utilizados según criterios de fecha. Para datos de acceso poco frecuente, los índices TTL son índices especiales de un solo campo que eliminan automáticamente los documentos de una colección después de un período específico o a una hora determinada. Esto resulta especialmente útil para datos como registros, información de sesión o datos de eventos que solo deben conservarse durante un tiempo limitado. Para crear un índice TTL, puede definir un índice en un campo que contenga valores de fecha y especificar un tiempo de vida en segundos.

Atlas también le proporciona herramientas automatizadas, como el Asesor de Rendimiento, para identificar y optimizar consultas ineficientes añadiendo o eliminando un índice o modificando la estructura de consultas de su cliente. Puede reducir el tiempo de procesamiento innecesario y el consumo de recursos siguiendo las recomendaciones prácticas del Asesor de Rendimiento para mejorar el rendimiento de sus consultas. Además, puede aprovechar las recomendaciones inteligentes de índices que ofrece Atlas para optimizar la recuperación de datos y minimizar los recursos necesarios para las operaciones de la base de datos.

Recomendaciones para la escalabilidad de Atlas

Ejemplos de automatización: Escalabilidad de Atlas

Los siguientes ejemplos permiten el escalado automático del cómputo y el almacenamiento mediante herramientas Atlas para la automatización.

Estos ejemplos también se aplican a otras configuraciones recomendadas, entre ellas:

{
    "clusterType": "REPLICASET",
    "links": [],
    "name": "CustomerPortalProd",
    "mongoDBMajorVersion": "8.0",
    "replicationSpecs": [
      {
        "numShards": 1,
        "regionConfigs": [
          {
            "electableSpecs": {
              "instanceSize": "M30",
              "nodeCount": 3
            },
            "priority": 7,
            "providerName": "GCP",
            "regionName": "EASTERN_US",
            "analyticsSpecs": {
              "nodeCount": 0,
              "instanceSize": "M30"
            },
            "autoScaling": {
              "compute": {
                "enabled": true,
                "scaleDownEnabled": true
              },
              "diskGB": {
                "enabled": true
              }
            },
            "readOnlySpecs": {
              "nodeCount": 0,
              "instanceSize": "M30"
            }
          }
        ],
        "zoneName": "Zone 1"
      }
    ]
  }

atlas cluster create --projectId 5e2211c17a3e5a48f5497de3 --file cluster.json

# Create a Group to Assign to Project
resource "mongodbatlas_team" "project_group" {
  org_id = var.atlas_org_id
  name   = var.atlas_group_name
  usernames = [
    "user1@example.com",
    "user2@example.com"
  ]
}
# Create a Project
resource "mongodbatlas_project" "atlas-project" {
  org_id = var.atlas_org_id
  name = var.atlas_project_name
}
# Assign the team to project with specific roles
resource "mongodbatlas_team_project_assignment" "project_team" {
  project_id = mongodbatlas_project.atlas-project.id
  team_id    = mongodbatlas_team.project_group.team_id
  role_names = ["GROUP_READ_ONLY", "GROUP_CLUSTER_MANAGER"]
}
# Create an Atlas Advanced Cluster
resource "mongodbatlas_advanced_cluster" "atlas-cluster" {
  project_id = mongodbatlas_project.atlas-project.id
  name = "ClusterPortalProd"
  cluster_type = "REPLICASET"
  mongo_db_major_version = var.mongodb_version
  use_effective_fields = true
  replication_specs = [
    {
      region_configs = [
        {
          electable_specs = {
            instance_size = var.cluster_instance_size_name
            node_count    = 3
            disk_size_gb  = var.disk_size_gb
          }
          auto_scaling = {
            disk_gb_enabled = var.auto_scaling_disk_gb_enabled
            compute_enabled = var.auto_scaling_compute_enabled
            compute_max_instance_size = var.compute_max_instance_size
          }
          priority      = 7
          provider_name = var.cloud_provider
          region_name   = var.atlas_region
        }
      ]
    }
  ]
  tags = {
    BU       = "ConsumerProducts"
    TeamName = "TeamA"
    AppName  = "ProductManagementApp"
    Env      = "Production"
    Version  = "8.0"
   Email    = "marissa@example.com"
  }
}
# Outputs to Display
output "atlas_cluster_connection_string" { value = mongodbatlas_advanced_cluster.atlas-cluster.connection_strings.standard_srv }
output "project_name"      { value = mongodbatlas_project.atlas-project.name }

replication_specs = [
  {
    region_configs = [
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 2
        }
        provider_name = "GCP"
        priority      = 7
        region_name   = "NORTH_AMERICA_NORTHEAST_1"
      },
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 3
        }
        provider_name = "GCP"
        priority      = 6
        region_name   = "WESTERN_US"
      }
    ]
  }
]

# Atlas Organization ID
variable "atlas_org_id" {
  type        = string
  description = "Atlas Organization ID"
}
# Atlas Project Name
variable "atlas_project_name" {
  type        = string
  description = "Atlas Project Name"
}
# Atlas Group Name
variable "atlas_group_name" {
  type        = string
  description = "Atlas Group Name"
}
# Atlas Project Environment
variable "environment" {
  type        = string
  description = "The environment to be built"
}
# Cluster Instance Size Name
variable "cluster_instance_size_name" {
  type        = string
  description = "Cluster instance size name"
}
# Cloud Provider to Host Atlas Cluster
variable "cloud_provider" {
  type        = string
  description = "AWS or GCP or Azure"
}
# Atlas Region
variable "atlas_region" {
  type        = string
  description = "Atlas region where resources will be created"
}
# MongoDB Version
variable "mongodb_version" {
  type        = string
  description = "MongoDB Version"
}
# Storage Auto-scaling Enablement Flag
variable "auto_scaling_disk_gb_enabled" {
  type        = bool
  description = "Flag that specifies whether disk auto-scaling is enabled"
}
# Compute Auto-scaling Enablement Flag
variable "auto_scaling_compute_enabled" {
  type        = bool
  description = "Flag that specifies whether cluster tier auto-scaling is enabled"
}
# Disk Size in GB
variable "disk_size_gb" {
  type        = int
  description = "Disk Size in GB"
}

atlas_org_id = "32b6e34b3d91647abb20e7b8"
atlas_project_name = "Customer Portal - Prod"
atlas_group_name = "Atlas Group"
environment = "prod"
cluster_instance_size_name = "M30"
cloud_provider = "AWS"
atlas_region = "US_WEST_2"
mongodb_version = "8.0"
auto_scaling_disk_gb_enabled = true
auto_scaling_compute_enabled = true
disk_size_gb = 40000

# Define the MongoDB Atlas Provider
terraform {
  required_providers {
    mongodbatlas = {
      source = "mongodb/mongodbatlas"
      version = "~> 2.2"
    }
  }
  required_version = ">= 1.0"
}
# Configure the MongoDB Atlas Provider
provider "mongodbatlas" {
  # Legacy API key authentication (backward compatibility)
  public_key  = var.mongodbatlas_public_key
  private_key = var.mongodbatlas_private_key
  # Recommended: Service account authentication
  # Uncomment and configure the following for service account auth:
  # service_account_id = var.mongodb_service_account_id
  # private_key_file   = var.mongodb_service_account_key_file
}

terraform init

terraform plan

terraform apply