Comienza con Terraform y el proveedor de MongoDB Atlas

Crear y navegar a un directorio vacío.

mkdir terraform-proj
cd terraform-proj

Crea tus archivos de terraform.

Crea los archivos main.tf, provider.tf, variables.tf y versions.tf.

touch main.tf provider.tf variables.tf versions.tf

Rellenar archivos de soporte.

Agregue el siguiente contenido a provider.tf:

provider "mongodbatlas" {
  client_id     = var.client_id
  client_secret = var.client_secret
}

Agregue el siguiente contenido a variables.tf:

variable "client_id" {
  description = "Atlas Service Account client ID"
  type        = string
}
variable "client_secret" {
  description = "Atlas Service Account client secret"
  type        = string
  sensitive   = true
}
variable "org_id" {
  description = "Atlas organization ID"
  type        = string
}

Agregue el siguiente contenido a versions.tf:

terraform {
  required_providers {
    mongodbatlas = {
      source  = "mongodb/mongodbatlas"
      version = "~> 2.2"
    }
  }
  required_version = "~> 1.0"
}

Configura los contenidos de main.tf.

Agregue el siguiente contenido a su archivo main.tf:

module "project" {
  source = "terraform-mongodbatlas-modules/project/mongodbatlas"
  name   = "tenant-example-project"
  org_id = var.org_id
}
resource "mongodbatlas_advanced_cluster" "this" {
  project_id   = module.project.id
  name         = "TenantCluster"
  cluster_type = "REPLICASET"
  replication_specs = [
    {
      region_configs = [
        {
          provider_name         = "TENANT"
          backing_provider_name = "AWS"
          region_name           = "US_EAST_1"
          priority              = 7
          electable_specs = {
            instance_size = "M0"
          }
        }
      ]
    }
  ]
}

Si trabaja con un proveedor de nube o una región diferente, puede actualizar los siguientes campos para que coincidan con su entorno.

El recurso mongodbatlas_advanced_cluster, y las fuentes de datos singular (mongodbatlas_advanced_cluster) y plural (mongodbatlas_advanced_clusters), exponen database_edition y el atributo de solo lectura effective_database_edition. Dado que database_edition es opcional, utilice effective_database_edition para confirmar qué edición asignó Atlas, incluso si usted no la configuró.

Para crear un clúster dedicado en Atlas Infinite, configure database_edition en "INFINITE" y compute_enabled en auto_scaling, como se muestra en el siguiente ejemplo:

resource "mongodbatlas_advanced_cluster" "infinite" {
  project_id       = module.project.id
  name             = "InfiniteCluster"
  cluster_type     = "REPLICASET"
  database_edition = "INFINITE"
  replication_specs = [
    {
      region_configs = [
        {
          provider_name = "AWS"
          priority      = 7
          region_name   = "US_EAST_1"
          electable_specs = {
            instance_size = "M10"
            node_count    = 2
          }
          auto_scaling = {
            compute_enabled           = true
            compute_max_instance_size = "M60_GEN_2"
            storage_config = {
              shard_size_limit_gb = 10240
            }
          }
        }
      ]
    }
  ]
}

Los clústeres dedicados de Atlas Infinite solo admiten el tipo de clúster REPLICASET.

compute_max_instance_size es necesario cuando compute_enabled es true. Los clústeres M30+ Atlas Infinite solo están disponibles en AWS Gen2, así que agregue _GEN_2 al nombre del nivel, como en M60_GEN_2. Para obtener más información, consulte Clústeres dedicados Gen2.

Un clúster Atlas Infinite tiene dos nodos de cómputo seleccionables, uno principal y otro en espera, así que configure node_count en 2. Para obtener más información, consulte Replicación y conmutación por error.

Para gestionar más lecturas o aislar las consultas analíticas de la carga de trabajo operativa, añada nodos de solo lectura o analíticos configurando read_only_specs o analytics_specs junto con electable_specs en el mismo objeto region_configs. Para obtener más información, consulte Aislamiento de carga de trabajo en clústeres de Atlas Infinite.

storage_config.shard_size_limit_gb Solo es necesario si incluye storage_config. Si omite storage_config, Atlas aplica el límite máximo de almacenamiento predeterminado. Para obtener más información, consulte Límite máximo de almacenamiento.

(Opcional) Parámetros de visualización.

Puedes mostrar información desde tu configuración de Terraform en la ventana de tu terminal. Esto resulta útil para valores que no conocerás hasta que Atlas cree los recursos, como tu cadena de conexión.

Si deseas mostrar tus parámetros después de implementar tu proyecto, agrega algunas líneas de código de salida a tu archivo main.tf.

Inicializa tu proyecto.

Para inicializar tu proyecto, ejecuta el siguiente comando:

terraform init

Este comando también descarga e instala el proveedor de MongoDB Atlas, si aún no lo has hecho.

Ver tu plan de ejecución.

Para ver el plan de ejecución, ejecute el siguiente comando:

terraform plan

Terraform describe los cambios que planea realizar. Si el resultado no es lo que esperas, podría haber un problema en tu archivo main.tf.

Implementa tu infraestructura.

Para implementar su infraestructura, ejecute el siguiente comando:

terraform apply

Cuando se le pida Do you want to perform these actions?, introduzca yes.