Orientações para organizações, projetos e clusters do Atlas

# Create a Project
resource "mongodbatlas_project" "atlas-project" {
  org_id = var.atlas_org_id
  name = var.atlas_project_name
}
# Create an Atlas Advanced Cluster
resource "mongodbatlas_advanced_cluster" "atlas-cluster" {
  project_id = mongodbatlas_project.atlas-project.id
  name = "ClusterPortalDev"
  cluster_type = "REPLICASET"
  mongo_db_major_version = var.mongodb_version
  replication_specs = [
    {
      region_configs = [
        {
          electable_specs = {
            instance_size = var.cluster_instance_size_name
            node_count    = 3
          }
          auto_scaling = {
            compute_enabled = true
            compute_scale_down_enabled = true
            compute_max_instance_size = "M60"
            compute_min_instance_size = "M10"
          }
          priority      = 7
          provider_name = var.cloud_provider
          region_name   = var.atlas_region
        }
      ]
    }
  ]
  tags = {
    BU       = "ConsumerProducts"
    TeamName = "TeamA"
    AppName  = "ProductManagementApp"
    Env      = "Test"
    Version  = "8.0"
   Email    = "marissa@example.com"
  }
  # MongoDB recommends enabling auto-scaling
  # When auto-scaling is enabled, Atlas may change the instance size, and this lifecycle
  # block prevents Terraform from reverting Atlas auto-scaling changes
  # that modify instance size back to the original configured value
  lifecycle {
    ignore_changes = [
      replication_specs[0].region_configs[0].electable_specs.instance_size
    ]
  }
}
# Outputs to Display
output "atlas_cluster_connection_string" { value = mongodbatlas_advanced_cluster.atlas-cluster.connection_strings.0.standard_srv }
output "project_name"      { value = mongodbatlas_project.atlas-project.name }

replication_specs = [
  {
    region_configs = [
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 2
        }
        auto_scaling = {
          compute_enabled = true
          compute_scale_down_enabled = true
          compute_max_instance_size = "M60"
          compute_min_instance_size = "M10"
        }
        provider_name = "GCP"
        priority      = 7
        region_name   = "NORTH_AMERICA_NORTHEAST_1"
      },
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 3
        }
        auto_scaling = {
          compute_enabled = true
          compute_scale_down_enabled = true
          compute_max_instance_size = "M60"
          compute_min_instance_size = "M10"
        }
        provider_name = "GCP"
        priority      = 6
        region_name   = "WESTERN_US"
      }
    ]
  }
]
# MongoDB recommends enabling auto-scaling
# When auto-scaling is enabled, Atlas may change the instance size, and this lifecycle
# block prevents Terraform from reverting Atlas auto-scaling changes
# that modify instance size back to the original configured value
lifecycle {
  ignore_changes = [
    replication_specs[0].region_configs[0].electable_specs.instance_size,
    replication_specs[0].region_configs[1].electable_specs.instance_size
  ]
}

# MongoDB Atlas Provider Authentication Variables
# Legacy API key authentication (backward compatibility)
variable "mongodbatlas_public_key" {
  type        = string
  description = "MongoDB Atlas API public key"
  sensitive   = true
}
variable "mongodbatlas_private_key" {
  type        = string
  description = "MongoDB Atlas API private key"
  sensitive   = true
}
# Recommended: Service account authentication
variable "mongodb_service_account_id" {
  type        = string
  description = "MongoDB service account ID for authentication"
  sensitive   = true
  default     = null
}
variable "mongodb_service_account_key_file" {
  type        = string
  description = "Path to MongoDB service account private key file"
  sensitive   = true
  default     = null
}
# Atlas Organization ID
variable "atlas_org_id" {
  type        = string
  description = "Atlas Organization ID"
}
# Atlas Project Name
variable "atlas_project_name" {
  type        = string
  description = "Atlas Project Name"
}
# Atlas Project Environment
variable "environment" {
  type        = string
  description = "The environment to be built"
}
# Cluster Instance Size Name
variable "cluster_instance_size_name" {
  type        = string
  description = "Cluster instance size name"
}
# Cloud Provider to Host Atlas Cluster
variable "cloud_provider" {
  type        = string
  description = "AWS or GCP or Azure"
}
# Atlas Region
variable "atlas_region" {
  type        = string
  description = "Atlas region where resources will be created"
}
# MongoDB Version
variable "mongodb_version" {
  type        = string
  description = "MongoDB Version"
}
# Atlas Group Name
variable "atlas_group_name" {
  type        = string
  description = "Atlas Group Name"
}

atlas_org_id = "32b6e34b3d91647abb20e7b8"
atlas_project_name = "Customer Portal - Dev"
environment = "dev"
cluster_instance_size_name = "M10"
cloud_provider = "AWS"
atlas_region = "US_WEST_2"
mongodb_version = "8.0"

# Define the MongoDB Atlas Provider
terraform {
  required_providers {
    mongodbatlas = {
      source = "mongodb/mongodbatlas"
      version = "~> 2.2"
    }
  }
  required_version = ">= 1.0"
}
# Configure the MongoDB Atlas Provider
provider "mongodbatlas" {
  # Legacy API key authentication (backward compatibility)
  public_key  = var.mongodbatlas_public_key
  private_key = var.mongodbatlas_private_key
  # Recommended: Service account authentication
  # Uncomment and configure the following for service account auth:
  # service_account_id = var.mongodb_service_account_id
  # private_key_file   = var.mongodb_service_account_key_file
}

# Create a Group to Assign to Project
resource "mongodbatlas_team" "project_group" {
  org_id = var.atlas_org_id
  name   = var.atlas_group_name
  usernames = [
    "user1@example.com",
    "user2@example.com"
  ]
}
# Create a Project
resource "mongodbatlas_project" "atlas-project" {
  org_id = var.atlas_org_id
  name = var.atlas_project_name
}
# Assign the team to project with specific roles
resource "mongodbatlas_team_project_assignment" "project_team" {
  project_id = mongodbatlas_project.atlas-project.id
  team_id    = mongodbatlas_team.project_group.team_id
  role_names = ["GROUP_READ_ONLY", "GROUP_CLUSTER_MANAGER"]
}
# Create an Atlas Advanced Cluster
resource "mongodbatlas_advanced_cluster" "atlas-cluster" {
  project_id = mongodbatlas_project.atlas-project.id
  name = "ClusterPortalProd"
  cluster_type = "REPLICASET"
  mongo_db_major_version = var.mongodb_version
  replication_specs = [
    {
      region_configs = [
        {
          electable_specs = {
            instance_size = var.cluster_instance_size_name
            node_count    = 3
            disk_size_gb  = var.disk_size_gb
          }
          auto_scaling = {
            disk_gb_enabled = var.auto_scaling_disk_gb_enabled
            compute_enabled = var.auto_scaling_compute_enabled
            compute_max_instance_size = var.compute_max_instance_size
          }
          priority      = 7
          provider_name = var.cloud_provider
          region_name   = var.atlas_region
        }
      ]
    }
  ]
  # Prevent Terraform from reverting auto-scaling changes
  lifecycle {
    ignore_changes = [
      replication_specs[0].region_configs[0].electable_specs.instance_size,
      replication_specs[0].region_configs[0].electable_specs.disk_size_gb
    ]
  }
  tags = {
    BU       = "ConsumerProducts"
    TeamName = "TeamA"
    AppName  = "ProductManagementApp"
    Env      = "Production"
    Version  = "8.0"
   Email    = "marissa@example.com"
  }
}
# Outputs to Display
output "atlas_cluster_connection_string" { value = mongodbatlas_advanced_cluster.atlas-cluster.connection_strings.standard_srv }
output "project_name"      { value = mongodbatlas_project.atlas-project.name }

replication_specs = [
  {
    region_configs = [
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 2
        }
        provider_name = "GCP"
        priority      = 7
        region_name   = "NORTH_AMERICA_NORTHEAST_1"
      },
      {
        electable_specs = {
          instance_size = "M10"
          node_count    = 3
        }
        provider_name = "GCP"
        priority      = 6
        region_name   = "WESTERN_US"
      }
    ]
  }
]

# MongoDB Atlas Provider Authentication Variables
# Legacy API key authentication (backward compatibility)
variable "mongodbatlas_public_key" {
  type        = string
  description = "MongoDB Atlas API public key"
  sensitive   = true
}
variable "mongodbatlas_private_key" {
  type        = string
  description = "MongoDB Atlas API private key"
  sensitive   = true
}
# Recommended: Service account authentication
variable "mongodb_service_account_id" {
  type        = string
  description = "MongoDB service account ID for authentication"
  sensitive   = true
  default     = null
}
variable "mongodb_service_account_key_file" {
  type        = string
  description = "Path to MongoDB service account private key file"
  sensitive   = true
  default     = null
}
# Atlas Organization ID
variable "atlas_org_id" {
  type        = string
  description = "Atlas Organization ID"
}
# Atlas Project Name
variable "atlas_project_name" {
  type        = string
  description = "Atlas Project Name"
}
# Atlas Project Environment
variable "environment" {
  type        = string
  description = "The environment to be built"
}
# Cluster Instance Size Name
variable "cluster_instance_size_name" {
  type        = string
  description = "Cluster instance size name"
}
# Cloud Provider to Host Atlas Cluster
variable "cloud_provider" {
  type        = string
  description = "AWS or GCP or Azure"
}
# Atlas Region
variable "atlas_region" {
  type        = string
  description = "Atlas region where resources will be created"
}
# MongoDB Version
variable "mongodb_version" {
  type        = string
  description = "MongoDB Version"
}
# Atlas Group Name
variable "atlas_group_name" {
  type        = string
  description = "Atlas Group Name"
}

atlas_org_id = "32b6e34b3d91647abb20e7b8"
atlas_project_name = "Customer Portal - Prod"
environment = "prod"
cluster_instance_size_name = "M30"
cloud_provider = "AWS"
atlas_region = "US_WEST_2"
mongodb_version = "8.0"
atlas_group_name = "Atlas Group"

# Define the MongoDB Atlas Provider
terraform {
  required_providers {
    mongodbatlas = {
      source = "mongodb/mongodbatlas"
      version = "~> 2.2"
    }
  }
  required_version = ">= 1.0"
}
# Configure the MongoDB Atlas Provider
provider "mongodbatlas" {
  # Legacy API key authentication (backward compatibility)
  public_key  = var.mongodbatlas_public_key
  private_key = var.mongodbatlas_private_key
  # Recommended: Service account authentication
  # Uncomment and configure the following for service account auth:
  # service_account_id = var.mongodb_service_account_id
  # private_key_file   = var.mongodb_service_account_key_file
}